#include <TroykaMQ.h>
#include <ARpcDevice.h>
//--------------------------------
#define RELAY_PIN 19
#define PIN_MQ135 A0
#define SPEED_1 5
#define DIR_1 4
#define SPEED_2 6
#define DIR_2 7
#define trigPin 10
#define echoPin 11
#define vcc 8
#define water 12
//--------------------------------
MQ135 mq135(PIN_MQ135);
int minlevel, maxlevel, optimal, levelscnd, levelfst, level, distWater = 0;
//IOT Часть
unsigned long newTime=0,prevSinTime=0;
const char *deviceName="IoT_Domino";//имя устройства
const ARpcUuid deviceId("{13657853-57f4-41fd-904a-d3e6c6d0aaa1}");//идентификатор устройства
const char *sensorsDef="<sensors>"
"<sensor name=\"gas\" type=\"u32_sv\"/>" // Датчик CO2
"<sensor name=\"distance\" type=\"u32_sv\"/>"
"</sensors>";
//--------------------------------
class WriteCallback
:public ARpcIWriteCallback
{
public:
virtual void writeData(const char *data,unsigned long sz)
{
Serial.write(data,sz);
}
virtual void writeStr(const char *str)
{
Serial.print(str);
}
virtual void writeStr(const __FlashStringHelper *str)
{
Serial.print(str);
}
}wcb;
//-------------------------------
ARpcDevice dev(300,&wcb,&deviceId,deviceName);

void setup() {
Serial.begin(9600);
pinMode(water, INPUT_PULLUP);
pinMode(RELAY_PIN, OUTPUT);
pinMode(vcc, OUTPUT);
pinMode(trigPin, OUTPUT);
pinMode(echoPin, INPUT);
digitalWrite(vcc, HIGH);
for (int i = 4; i < 8; i++) {
pinMode(i, OUTPUT);
}
mq135.calibrate();
while(digitalRead(water) == 1 || get_distance() > 8) {
digitalWrite(DIR_1, HIGH);
analogWrite(SPEED_1, 255);
delay(1000);
analogWrite(SPEED_1, 0);
}
levelfst = mq135.readCO2();
delay(10000);
levelscnd = mq135.readCO2();
optimal = (levelfst + levelscnd) / 2;
minlevel = optimal - 20;
maxlevel = optimal + 20;
dev.disp().setSensors(sensorsDef);
dev.resetStream();
}

void loop() {
distWater = get_distance();
level = mq135.readCO2();
Serial.print("CO2: ");
Serial.println(level);
//---------------------------------------------------------------------------------
while(Serial.available())
dev.putByte(Serial.read());//если данные есть, передаем в объект библиотеки
newTime=millis();
if((newTime-prevSinTime)>=10000) { //если оно на 10000 мсек больше предыдущего
dev.disp().writeMeasurement("gas",String(level).c_str());
dev.disp().writeMeasurement("distance",String(distWater).c_str());
prevSinTime=newTime;
}
//---------------------------------------------------------------------------------
delay(1);
// Если CO2 низкий:
if (level < minlevel) {
while(get_distance() < 11){
digitalWrite(DIR_2, HIGH);
analogWrite(SPEED_2, 255);
delay(1000); //ВРЕМЯ ЗАСЕЧЬ ПО ФАКТУ ДО ДОСТИЖЕНИЯ МИНИМАЛЬНОЙ ОТМЕТКИ
analogWrite(SPEED_2, 0);
// Закачка воды
}

while(digitalRead(water) == 1 || get_distance() > 8) {
digitalWrite(DIR_1, HIGH);
analogWrite(SPEED_1, 255);
delay(100);
analogWrite(SPEED_1, 0);
}
}
// Если CO2 высокий
else if (level > maxlevel) {
digitalWrite(RELAY_PIN, HIGH); // Включение реле
while (level > maxlevel) {
delay(1000);
level = mq135.readCO2();
}
digitalWrite(RELAY_PIN, LOW);
}
delay(1000);
}

int get_distance(){
int duration, distance;
digitalWrite(trigPin, LOW);
delayMicroseconds(2);
digitalWrite(trigPin, HIGH);
delayMicroseconds(10);
digitalWrite(trigPin, LOW);
duration = pulseIn(echoPin, HIGH);
distance= duration / 58;
return distance;
}